고도몰5 쇼핑몰 솔루션을 친애하는 나였지만 대량등록이 200개도 넘기기 힘듭니다. 셀내용이 많으면 오류가 더 많이 나지요
이래서 무슨 대량등록이라고 할 수 있겠습니까?
답답한 노릇이죠
5000개의 상품을 대량등록으로 진행하려면 25번 이상의 단순 노가다가 발생됩니다. 시간이 금인데 그들은 우리의 시간을 헛되게 합니다. 그래서 시간을 아껴보고자 검색 들어갔지요
http://blog.naver.com/jsk005/150180850094
자세한 설명과 함께 파일까지 올려두셨습니다.
파일을 헤집어보면 다음과 같습니다.
Option Explicit
Sub split_As_per_Rows()
' 지정한 행만큼씩 파일을 나눠서 저장하는 VBA
Dim rngAll As Range '모든 영역을 저장할 변수
Dim SplitLine As Integer '몇 행씩 나눌지를 정하는 변수
Dim rowsCount As Long, colsCount As Integer '행 및 열의 갯수 저장할 변수
Dim strPath As String '파일저장 경로를 넣을 변수
Dim i As Long '반복구문 숫자 증가에 사용할 변수
Dim rowsNo As Long '행 증가에 사용할 변수
Dim rngSplit As Range '나누어진 영역을 저장할 변수
Dim strName As String
Application.ScreenUpdating = False '화면 업데이트 (일시)정지
Set rngAll = ActiveSheet.UsedRange '사용전체영역을 변수에 넣음
SplitLine = 5000 '이 숫자대로 파일이 나누어지므로 이 숫자를 원하는 만큼 변경하여 사용하면 됨
rowsCount = rngAll.Rows.Count '전체 행의 숫자를 행 변수에 넣음
colsCount = rngAll.Columns.Count '전체 열의 숫자를 열 변수에 넣음
strPath = ThisWorkbook.Path & Application.PathSeparator '저장 경로로 현재 파일이 있는 경로에 저장
With ThisWorkbook
strName = Left(.Name, Len(.Name) - 5) 'Excel 파일의 확장자 제거. 만약 xls 파일이면 숫자를 4로 변경
End With
For i = 2 To rowsCount Step SplitLine 'SplitLine 만큼씩 증가하며 반복
rowsNo = i + SplitLine '행도 지정한 SplitLine 만큼씩 증가
Set rngSplit = Range(Cells(i, 1), Cells(rowsNo + 1, colsCount)) '나누어진 영역을 변수에 넣음
Workbooks.Add '새로운 workbook을 생성
rngAll.Rows(1).SpecialCells(2).Copy Cells(1, 1) '첫줄 제목을 각 workbook에 복사
Range(Cells(2, 1), Cells(SplitLine + 1, colsCount)) = rngSplit.Value '2번째 행부터 나누어진 영역(SplitLine 만큼)을 복사
Columns.AutoFit '열너비 자동맞춤
ActiveWorkbook.SaveAs strPath & strName & "(" & ((i - 1) \ SplitLine) + 1 & ").xlsx", FileFormat:=xlOpenXMLWorkbook
'현재 파일이 있는 경로에 현재파일명 + SplitLine 만큼씩 나눠서 몫으로 카운트하면서 저장
ActiveWorkbook.Close '새로 만든 workbook을 저장
Next i
Set rngAll = Nothing '개체변수들 초기화(사용 메모리 비우기)
Set rngSplit = Nothing
End Sub
알아보기 힘든 명령어지만 하나하나 뜯어보면 그 의미를 알수 있습니다.
카쎈님들 화이팅!
OH 
루비 